ICsv RemoveColumn (add/remove CSV column)

[Lucas]

How can I remove a column in ICsv?

[Gintaras]

ICsv cannot change column count. Create new CSV without the column.

[Lucas]

Can you show me an example?

[Gintaras]

Function CsvRemoveColumn

Code:

Copy      Help

;/
function ICsv&csv column

;Removes CSV column.

;column - 0-based column index.


int i j nr(csv.RowCount) nc(csv.ColumnCount)
ARRAY(str) a.create(nr)

for i 0 nr
,str& s=a[i]
,for j 0 nc
,,if(j=column) continue
,,lpstr v=csv.Cell(i j)
,,s.fromn(s s.len v len(v)+1)

csv.Clear
for i 0 nr
,csv.AddRowMS(i nc-1 a[i])

[Lucas]

Perfect!

Thanks.

[Gintaras]

Function CsvAddColumn

Code:

Copy      Help

;/
function ICsv&csv column

;Adds CSV column.
;It will be empty. Use Cell(r c)="value" to set its value.

;column - 0-based index of the new column. To add to the end, can be >= column count or -1.


int i j nr(csv.RowCount) nc(csv.ColumnCount)
ARRAY(str) a.create(nr)

if(column<0 or column>nc) column=nc
nc+1

for i 0 nr
,str& s=a[i]
,for j 0 nc
,,if(j=column)
,,,s.fromn(s s.len "" 1)
,,else
,,,lpstr v=csv.Cell(i j-(j>column))
,,,s.fromn(s s.len v len(v)+1)

csv.Clear
for i 0 nr
,csv.AddRowMS(i nc a[i])

[Lucas]

Thanks again.