How to detect if a file is being used ?

[Gintaras]

Retry when fails

Code:

Copy      Help

;g1
FileMove from to
err
,if(!FileExists(from)) ret
,wait 0.5; goto g1

----------------------------------
or use one of these functions

Function FileTryOpenForReadWrite

Code:

Copy      Help

;/
function# $filePath

;Returns 0 if the specified file exists and can be opened for read/write access (and can be moved etc).
;Else returns an error code.
;Some error codes:
;;;ERROR_FILE_NOT_FOUND (2) - the file does not exist.
;;;ERROR_PATH_NOT_FOUND (3) - the directory does not exist.
;;;ERROR_ACCESS_DENIED (5) - read-only or protected.
;;;ERROR_SHARING_VIOLATION (32) - is already open, for example by another process.


_s.expandpath(filePath)
int h=CreateFileW(@_s GENERIC_READ|GENERIC_WRITE 0 0 OPEN_EXISTING FILE_ATTRIBUTE_NORMAL 0)
if(h==INVALID_HANDLE_VALUE) ret GetLastError
CloseHandle h

Function FileTryOpenForRead

Code:

Copy      Help

;/
function# $filePath

;Returns 0 if the specified file exists and can be opened for read access.
;Else returns an error code.
;Some error codes:
;;;ERROR_FILE_NOT_FOUND (2) - the file does not exist.
;;;ERROR_PATH_NOT_FOUND (3) - the directory does not exist.
;;;ERROR_SHARING_VIOLATION (32) - is already open, for example by another process.


_s.expandpath(filePath)
int h=CreateFileW(@_s GENERIC_READ 0 0 OPEN_EXISTING FILE_ATTRIBUTE_NORMAL 0)
if(h==INVALID_HANDLE_VALUE) ret GetLastError
CloseHandle h

example

Code:

Copy      Help

out
str s="q:\test\file.txt"
sel FileTryOpenForReadWrite(s)
,case 0 out "can open and move"
,case ERROR_SHARING_VIOLATION out "cannot open, it is used by something"
,case [2,3] out "does not exist"
,case else out "cannot open, unknown error"